[meta-freescale] [meta-fsl-arm][PATCH v2 4/6] Add rcw recipe for Layerscape1 support

[Otavio Salvador]

On Wed, Aug 27, 2014 at 1:57 AM, Zhenhua Luo <zhenhua.luo at freescale.com> wrote:
> Signed-off-by: Zhenhua Luo <zhenhua.luo at freescale.com>

Same drill for the commit log.

> ---
>  recipes-bsp/rcw/rcw_git.bb | 50 ++++++++++++++++++++++++++++++++++++++++++++++
>  1 file changed, 50 insertions(+)
>  create mode 100644 recipes-bsp/rcw/rcw_git.bb
>
> diff --git a/recipes-bsp/rcw/rcw_git.bb b/recipes-bsp/rcw/rcw_git.bb
> new file mode 100644
> index 0000000..f6cd4d8
> --- /dev/null
> +++ b/recipes-bsp/rcw/rcw_git.bb
> @@ -0,0 +1,50 @@
> +SUMMARY = "Reset Configuration Word"
> +DESCRIPTION = "Reset Configuration Word - hardware boot-time parameters for the QorIQ targets"
> +LICENSE = "BSD"
> +LIC_FILES_CHKSUM = "file://rcw.py;beginline=8;endline=28;md5=9ba0b28922dd187b06b6c8ebcfdd208e"
> +
> +inherit deploy
> +
> +SRC_URI = "git://git.freescale.com/layerscape/ls1021a/rcw.git;branch=LS1-SDK"
> +SRCREV = "7b358441dfd35afbf01491649cc3f4396154a546"
> +
> +S = "${WORKDIR}/git"
> +
> +export PYTHON
> +do_compile_append () {
> +    if [ "ls1021aqds" = "${M}" ];then
> +       for img in `find ${S} -name "*qspiboot*.bin"`; do
> +           img_swap=`echo ${img} | awk '{sub("qspiboot","qspiboot_swap"); print $0}'`
> +           ${bindir}/tclsh ${M}/byte_swap.tcl ${img} ${img_swap} 8
> +       done
> +    fi

The tcl file needs to come from a dependency so we need, as I said in
the u-boot patch, split it out and have it as dependency here. Another
thing, this calls should be moved to the Makefile and have a
RCW_MACHINE concept or similar.

> +}
> +
> +do_install () {
> +    make install
> +
> +    M=`echo ${MACHINE} | sed s/-64b//g`
> +    for img in `find ${S} -name "*qspiboot_swap*.bin"`; do
> +        rcw_subdir="`dirname ${img} | xargs basename`"
> +        install ${img} ${S}/${M}/${M}/${rcw_subdir}
> +    done
> +
> +    install -d ${D}/boot/rcw
> +    cp -r ${S}/${M}/${M}/* ${D}/boot/rcw

This should be done in the Makefile.

> +}
> +
> +do_deploy () {
> +    M=`echo ${MACHINE} | sed s/-64b//g`
> +    install -d ${DEPLOYDIR}/rcw
> +    cp -r ${S}/${M}/${M}/* ${DEPLOYDIR}/rcw
> +}
> +addtask deploy after do_install
> +
> +PACKAGES += "${PN}-image"
> +FILES_${PN}-image += "/boot"
> +
> +ALLOW_EMPTY_${PN} = "1"
> +
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +COMPATIBLE_HOST_ls102xa = "arm-poky-linux-gnueabi"

This makes this not compatible with custom SDKs.

> +COMPATIBLE_MACHINE = "(ls1021aqds|ls1021atwr)"

I'd use SoC family.

> --
> 1.9.3
>
> --
> _______________________________________________
> meta-freescale mailing list
> meta-freescale at yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-freescale



-- 
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854            Mobile: +1 (347) 903-9750