[yocto] [PATCH][meta-qt4] sip: re-add 4.19

[akuster]

On 11/30/18 7:34 AM, Andreas Müller wrote:
> * Haven't tested this but it seems unlikely that python-pyqt builds properly
>   with '--sip-module PyQt5.sip' in meta-oe's sip

Why not fix the version in meta-oe?

- armin
> * I plan to move reworked sip to meta-qt5 and remove meta-oe's version
> * remove FILES_${PN} - not necessary
> * add "STRIP="" for native configure to avoid 'already stripped' warning
> * tested build of python-pyqt
>
> Signed-off-by: Andreas Müller <schnitzeltony at gmail.com>
> ---
>  recipes-qt4/recipes-python/sip_4.19.bb | 41 ++++++++++++++++++++++++++++++++++
>  1 file changed, 41 insertions(+)
>  create mode 100644 recipes-qt4/recipes-python/sip_4.19.bb
>
> diff --git a/recipes-qt4/recipes-python/sip_4.19.bb b/recipes-qt4/recipes-python/sip_4.19.bb
> new file mode 100644
> index 0000000..b43c2d2
> --- /dev/null
> +++ b/recipes-qt4/recipes-python/sip_4.19.bb
> @@ -0,0 +1,41 @@
> +SUMMARY = "SIP is a C++/Python Wrapper Generator"
> +HOMEPAGE = "http://www.riverbankcomputing.co.uk/sip"
> +SECTION = "devel"
> +LICENSE = "GPLv2+"
> +LIC_FILES_CHKSUM = "file://LICENSE-GPL2;md5=e91355d8a6f8bd8f7c699d62863c7303"
> +
> +inherit python-dir
> +
> +DEPENDS = "python"
> +
> +SRC_URI = "${SOURCEFORGE_MIRROR}/project/pyqt/sip/sip-${PV}/sip-${PV}.tar.gz"
> +SRC_URI[md5sum] = "be51a05065c9323b98a2ec2966c64e6a"
> +SRC_URI[sha256sum] = "014bf55f653e0d8bcc582705ef4fbd61e0859a36e959ab46d8fa060cdf0b5e27"
> +
> +BBCLASSEXTEND = "native"
> +
> +PACKAGES += "python-sip"
> +
> +do_configure_prepend_class-target() {
> +    echo "py_platform = linux" > sip.cfg
> +    echo "py_inc_dir = %(sysroot)/${includedir}/python%(py_major).%(py_minor)" >> sip.cfg
> +    echo "sip_bin_dir = ${D}/${bindir}" >> sip.cfg
> +    echo "sip_inc_dir = ${D}/${includedir}" >> sip.cfg
> +    echo "sip_module_dir = ${D}/${libdir}/python%(py_major).%(py_minor)/site-packages" >> sip.cfg
> +    echo "sip_sip_dir = ${D}/${datadir}/sip" >> sip.cfg
> +    python configure.py --configuration sip.cfg --sysroot ${STAGING_DIR_HOST} CC="${CC}" CXX="${CXX}" LINK="${CXX}" STRIP="" LINK_SHLIB="${CXX}" CFLAGS="${CFLAGS}" CXXFLAGS="${CXXFLAGS}" LFLAGS="${LDFLAGS}"
> +}
> +do_configure_prepend_class-native() {
> +    echo "py_platform = linux" > sip.cfg
> +    echo "py_inc_dir = ${includedir}/python%(py_major).%(py_minor)" >> sip.cfg
> +    echo "sip_bin_dir = ${D}/${bindir}" >> sip.cfg
> +    echo "sip_inc_dir = ${D}/${includedir}" >> sip.cfg
> +    echo "sip_module_dir = ${D}/${libdir}/python%(py_major).%(py_minor)/site-packages" >> sip.cfg
> +    echo "sip_sip_dir = ${D}/${datadir}/sip" >> sip.cfg
> +    python configure.py --configuration sip.cfg --sysroot ${STAGING_DIR_NATIVE} STRIP=""
> +}
> +do_install() {
> +    oe_runmake install
> +}
> +
> +FILES_python-sip = "${libdir}/${PYTHON_DIR}/site-packages/"