[meta-ti] [PATCH V2] ti-display-sharing: add recipe for fw integration

[Dan Murphy]

On 7/2/19 12:57 PM, Subhajit Paul wrote:
> Signed-off-by: Subhajit Paul <subhajit_paul at ti.com>
> ---
>   .../ti-display-sharing-firmware_git.bb             | 46 ++++++++++++++++++++++
>   1 file changed, 46 insertions(+)
>   create mode 100644 recipes-bsp/ti-display-sharing-fw/ti-display-sharing-firmware_git.bb
>
> diff --git a/recipes-bsp/ti-display-sharing-fw/ti-display-sharing-firmware_git.bb b/recipes-bsp/ti-display-sharing-fw/ti-display-sharing-firmware_git.bb
> new file mode 100644
> index 0000000..113102e
> --- /dev/null
> +++ b/recipes-bsp/ti-display-sharing-fw/ti-display-sharing-firmware_git.bb
> @@ -0,0 +1,46 @@
> +SUMMARY = "TI Display Sharing Firmware Packaging recipe"
> +
> +LICENSE = "TI-TFL"
> +LIC_FILES_CHKSUM = "file://LICENSE.ti;md5=b5aebf0668bdf95621259288c4a46d76"
> +
> +PV = "00.09.00.00-git${SRCPV}"
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +
> +inherit deploy
> +inherit update-alternatives
> +
> +PROTOCOL = "git"
> +BRANCH = "ti-linux-firmware"
> +SRCREV = "4a86f16df9b44798851e51fa465825710cda76cf"
> +
> +SRC_URI = "git://git.ti.com/processor-firmware/ti-linux-firmware.git;protocol=${PROTOCOL};branch=${BRANCH}"
> +
> +S = "${WORKDIR}/git"
> +
> +TI_DISP_SHARE_FW_DIR = "${S}/ti-display-sharing/"
> +TI_DISP_SHARE_FW_FILENAME = "ti-display-sharing-j721e.bin"
> +
> +# make sure that lib/firmware, and all its contents are part of the package
> +FILES_${PN} += "${base_libdir}/firmware"
> +
> +do_install() {
> +  install -d ${D}${base_libdir}/firmware
> +  install -m 0755 ${TI_DISP_SHARE_FW_DIR}/${TI_DISP_SHARE_FW_FILENAME} ${D}${base_libdir}/firmware
> +}
> +
> +TARGET_MAIN_R5FSS0_1 = "j7-main-r5f0_1-fw"
> +ALTERNATIVE_${PN} = "j7-main-r5f0_1-fw"
> +ALTERNATIVE_LINK_NAME[j7-main-r5f0_1-fw] = "${base_libdir}/firmware/${TARGET_MAIN_R5FSS0_1}"
> +ALTERNATIVE_TARGET[j7-main-r5f0_1-fw] = "${base_libdir}/firmware/${TI_DISP_SHARE_FW_FILENAME}"
> +ALTERNATIVE_PRIORITY = "9"
> +
> +# This is used to prevent the build system to strip the executables
> +INHIBIT_PACKAGE_STRIP = "1"
> +# This is used to prevent the build system to split the debug info in a separate file
> +INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
> +# As it likely to be a different arch from the Yocto build, disable checking by adding "arch" to INSANE_SKIP
> +INSANE_SKIP_${PN} += "arch"
> +
> +# we don't want to configure and build the source code
> +do_compile[noexec] = "1"
> +do_configure[noexec] = "1"


Reviewed-by: Dan Murphy <dmurphy at ti.com>