[meta-ti] [PATCH] swtools: common tools for xdc-based component build

[Denys Dmytriyenko]

Can you please send the patches as an ordered series. Thanks.


On Fri, Sep 14, 2018 at 04:47:06PM -0400, Jianzhong Xu wrote:
> swtools: common tools for xdc-based component build
> 
> Add SWTOOLS which is needed to build xdc-based processor libs such as
> DSPLIB, MATHLIB, etc from source.
> 
> Signed-off-by: Jianzhong Xu <xuj at ti.com>
> ---
>  recipes-ti/includes/ti-paths.inc  |  2 ++
>  recipes-ti/swtools/swtools_git.bb | 44 +++++++++++++++++++++++++++++++++++++++
>  2 files changed, 46 insertions(+)
>  create mode 100644 recipes-ti/swtools/swtools_git.bb
> 
> diff --git a/recipes-ti/includes/ti-paths.inc b/recipes-ti/includes/ti-paths.inc
> index a401264..f797a2d 100644
> --- a/recipes-ti/includes/ti-paths.inc
> +++ b/recipes-ti/includes/ti-paths.inc
> @@ -39,6 +39,7 @@ export OSAL_INSTALL_DIR_RECIPE       = "${installdir}/ti-osal-tree"
>  export RTFS_INSTALL_DIR_RECIPE       = "${installdir}/ti-rtfs-tree"
>  export SYSBIOS_INSTALL_DIR_RECIPE    = "${installdir}/ti-sysbios-tree"
>  export SYSLINK_INSTALL_DIR_RECIPE    = "${installdir}/ti-syslink-tree"
> +export SWTOOLS_INSTALL_DIR_RECIPE    = "${installdir}/ti-swtools-tree"
>  export UIA_INSTALL_DIR_RECIPE        = "${installdir}/ti-uia-tree"
>  export VICPLIB_INSTALL_DIR_RECIPE    = "${installdir}/ti-vicplib-tree"
>  export XDAIS_INSTALL_DIR_RECIPE      = "${installdir}/ti-xdais-tree"
> @@ -97,6 +98,7 @@ export OSAL_INSTALL_DIR       = "${STAGING_DIR_TARGET}${OSAL_INSTALL_DIR_RECIPE}
>  export M4_TOOLCHAIN_INSTALL_DIR    = "${STAGING_DIR_NATIVE}${M4_TOOLCHAIN_INSTALL_DIR_RECIPE}"
>  export GCC_ARM_NONE_TOOLCHAIN      = "${STAGING_DIR_NATIVE}${GCC_ARM_NONE_TOOLCHAIN_RECIPE}"
>  export TI_CGT_PRU_INSTALL_DIR      = "${STAGING_DIR_NATIVE}${TI_CGT_PRU_INSTALL_DIR_RECIPE}"
> +export SWTOOLS_INSTALL_DIR         = "${STAGING_DIR_TARGET}${SWTOOLS_INSTALL_DIR_RECIPE}"
>  export DSPLIB_C66_INSTALL_DIR      = "${STAGING_DIR_TARGET}${DSPLIB_C66_INSTALL_DIR_RECIPE}"
>  export MATHLIB_C66_INSTALL_DIR     = "${STAGING_DIR_TARGET}${MATHLIB_C66_INSTALL_DIR_RECIPE}"
>  export IMGLIB_C66_INSTALL_DIR      = "${STAGING_DIR_TARGET}${IMGLIB_C66_INSTALL_DIR_RECIPE}"
> diff --git a/recipes-ti/swtools/swtools_git.bb b/recipes-ti/swtools/swtools_git.bb
> new file mode 100644
> index 0000000..425a069
> --- /dev/null
> +++ b/recipes-ti/swtools/swtools_git.bb
> @@ -0,0 +1,44 @@
> +SUMMARY = "TI Software Tools"
> +HOMEPAGE = "https://git.ti.com/ep-processor-libraries/swtools"
> +SECTION = "devel"
> +LICENSE = "BSD"
> +LIC_FILES_CHKSUM = "file://ti/mas/swtools/copyright.txt;md5=b1f52a1435051fdb18f8885b0384147d"
> +
> +require ../includes/ti-paths.inc
> +
> +DEPENDS = "ti-cgt6x-native \
> +           ti-sysbios \
> +           ti-xdctools-native"
> +
> +PV = "5_0_8"
> +PR = "r0"
> +S = "${WORKDIR}/git"
> +BRANCH = "master"
> +SRC_URI = "git://git.ti.com/ep-processor-libraries/swtools.git;protocol=git;branch=${BRANCH}"
> +SRCREV = "881267836907de650edadc56b8e57ab45428021d"
> +
> +export C64PCODEGENTOOL = "${CGTOOLS_INSTALL_DIR}"
> +export C674CODEGENTOOL = "${CGTOOLS_INSTALL_DIR}"
> +export C66CODEGENTOOL  = "${CGTOOLS_INSTALL_DIR}"
> +
> +PATH_append = ":${XDC_INSTALL_DIR}"
> +
> +XDCPATH .= "${XDCCGROOT}/include;${XDC_INSTALL_DIR}/packages;${SYSBIOS_INSTALL_DIR}/packages;"
> +
> +export XDCPATH
> +
> +do_compile() {
> +	cd ${S}/ti/mas/swtools
> +	xdc
> +}
> +
> +do_install() {
> +	CP_ARGS="-Prf --preserve=mode,timestamps --no-preserve=ownership"
> +	install -d ${D}${SWTOOLS_INSTALL_DIR_RECIPE}
> +	cp -pPrf ${S}/* ${D}${SWTOOLS_INSTALL_DIR_RECIPE}
> +}
> +
> +FILES_${PN}-dev += "${SWTOOLS_INSTALL_DIR_RECIPE}"
> +
> +INSANE_SKIP_${PN}-dev = "arch staticdev"
> +ALLOW_EMPTY_${PN} = "1"
> -- 
> 1.9.1
> 
> -- 
> _______________________________________________
> meta-ti mailing list
> meta-ti at yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti