[meta-ti] [PATCH v2] starterware-rtos: added recipe for RTOS starterware

Ivan Pang i-pang at ti.com
Mon Jun 5 11:09:40 PDT 2017


Signed-off-by: Ivan Pang <i-pang at ti.com>
---
 recipes-bsp/starterware/starterware-rtos_git.bb | 46 +++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 recipes-bsp/starterware/starterware-rtos_git.bb

diff --git a/recipes-bsp/starterware/starterware-rtos_git.bb b/recipes-bsp/starterware/starterware-rtos_git.bb
new file mode 100644
index 0000000..3fbe763
--- /dev/null
+++ b/recipes-bsp/starterware/starterware-rtos_git.bb
@@ -0,0 +1,46 @@
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://Makefile;beginline=1;endline=35;md5=286cbb5dce3e348294b6b025cff969b3"
+
+COMPATIBLE_MACHINE = "ti33x|ti43x"
+DEPENDS = "gcc-arm-none-eabi-native"
+
+require recipes-ti/includes/ti-staging.inc
+require recipes-ti/includes/ti-paths.inc
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+STARTERWARE_GIT_URI = "git://git.ti.com/keystone-rtos/starterware.git"
+STARTERWARE_GIT_PROTOCOL = "git"
+STARTERWARE_GIT_BRANCH = "master"
+
+# Below commit ID corresponds to "DEV.STARTERWARE.PROCSDK.02.01.01.02A"
+STARTERWARE_SRCREV = "d648ffc46a3508802ec5d4f70f3d0e8f970ce1fa"
+
+BRANCH = "${STARTERWARE_GIT_BRANCH}"
+SRC_URI = "${STARTERWARE_GIT_URI};protocol=${STARTERWARE_GIT_PROTOCOL};branch=${BRANCH}"
+
+SRCREV = "${STARTERWARE_SRCREV}"
+PV = "02.01.01.02A"
+PR = "r0"
+
+S = "${WORKDIR}/git"
+
+PARTNO_ti33x = "am335x"
+PARTNO_ti43x = "am437x"
+
+export TOOLCHAIN_PATH_A8 = "${GCC_ARM_NONE_TOOLCHAIN}"
+export TOOLCHAIN_PATH_A9 = "${GCC_ARM_NONE_TOOLCHAIN}"
+
+do_compile() {
+    cd build
+    ./release_${PARTNO}.sh
+}
+
+do_install() {
+    install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/starterware
+    find -name "*.tar" -exec tar xf {} --no-same-owner -C ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/starterware \;
+}
+
+FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages"
+
+INSANE_SKIP_${PN} = "arch staticdev"
-- 
1.9.1



More information about the meta-ti mailing list