[meta-intel] [fido][PATCH 3/3] meta-crystalforrest: qat recipe for riverforest
anujx.mittal at intel.com
anujx.mittal at intel.com
Sun Jul 5 22:28:39 PDT 2015
From: Anuj Mittal <anujx.mittal at intel.com>
This implements the support for Intel QAT 2.3.0-34
for Intel RiverForest platforms on YP Fido.
Signed-off-by: Anuj Mittal <anujx.mittal at intel.com>
---
.../recipes-extended/qat/qat_2.3.0-34.bb | 104 ++++++++++++++++++++
1 file changed, 104 insertions(+)
create mode 100644 meta-crystalforest/recipes-extended/qat/qat_2.3.0-34.bb
diff --git a/meta-crystalforest/recipes-extended/qat/qat_2.3.0-34.bb b/meta-crystalforest/recipes-extended/qat/qat_2.3.0-34.bb
new file mode 100644
index 0000000..31b366f
--- /dev/null
+++ b/meta-crystalforest/recipes-extended/qat/qat_2.3.0-34.bb
@@ -0,0 +1,104 @@
+DESCRIPTION = "Intel(r) QuickAssist Technology API"
+HOMEPAGE = "https://01.org/packet-processing/intel%C2%AE-quickassist-technology-drivers-and-patches"
+LICENSE = "BSD & GPLv2"
+LIC_FILES_CHKSUM = "file://LICENSE.GPL;md5=751419260aa954499f7abaabaa882bbe"
+DEPENDS += "zlib openssl"
+
+SRC_URI="https://01.org/sites/default/files/page/qatmux.l.${PV}.tgz;name=qat;subdir=${PN}-${PV}; \
+ file://qat_2.3.0-34-qat-remove-local-path-in-makefile.patch \
+ file://qat_2.3.0-34-qat-fix-firmware-output-path.patch \
+ file://qat_2.3.0-34-qat-add-generic-paths-to-makefile-for-install.patch \
+ file://qat_2.3.0-34-qat-build-all-the-sample-apps.patch \
+ file://qat_2.3.0-34-qat-tweak-sample-code-makefiles.patch \
+ file://qat_2.3.0-34-qat-copy-all-the-conf-files.patch \
+ "
+
+SRC_URI[qat.md5sum] = "9614bf598bc8e7eedc8adb6d29109033"
+SRC_URI[qat.sha256sum] = "1f9708de3c132258eaa488c82760f374b6b6838c85cafef2e8c61034fe0f7031"
+
+COMPATIBLE_MACHINE = "crystalforest"
+
+export QAT_VERSION = "2.3.0-34"
+export ICP_DH895X = "QAT1.6"
+export ICP_DRIVER_TYPE = "${ICP_DH895X}"
+export ICP_FIRMWARE_DIR="dh895xcc"
+export ICP_ROOT = "${WORKDIR}/${PN}-${PV}"
+export BUILD_DIR = "${ICP_ROOT}/${ICP_DH895X}/build"
+export KERNEL_SOURCE_ROOT = "${STAGING_KERNEL_DIR}"
+export ICP_BUILD_OUTPUT = "${BUILD_DIR}"
+export DEST_LIBDIR = "${libdir}"
+export DEST_BINDIR = "${bindir}"
+export QAT_KERNEL_VER = "${KERNEL_VERSION}"
+export SAMPLE_BUILD_OUTPUT = "${BUILD_DIR}"
+export MODULE_DIR = "${base_libdir}/modules/${KERNEL_VERSION}/kernel/drivers"
+
+B="${BUILD_DIR}"
+S="${ICP_ROOT}"
+
+inherit module
+inherit update-rc.d
+INITSCRIPT_NAME = "qat_service"
+
+#To get around the double slashes in paths in QAT makefiles
+PACKAGE_DEBUG_SPLIT_STYLE = "debug-without-src"
+
+do_fixsource() {
+ cd $ICP_ROOT/$ICP_DH895X
+ if [ $ICP_DRIVER_TYPE == $ICP_DH895X ] ; then
+ tar -zxof $ICP_DRIVER_TYPE*.L.*.tar.gz
+ if [ -e cpa_mux ]; then
+ mv cpa_mux ${ICP_ROOT}
+ fi
+ fi
+}
+
+addtask fixsource before do_patch after do_unpack
+
+do_compile () {
+ cd ${S}
+ export LD="${LD} --hash-style=gnu"
+ export MACHINE="${TARGET_ARCH}"
+ ./installer.sh build QAT1.6
+}
+
+do_install_prepend() {
+ cp -Pr ${B}/* ${D}
+}
+
+do_install() {
+ install -d ${D}/etc/udev/rules.d \
+ ${D}${includedir} \
+ ${D}${includedir}/dc \
+ ${D}${includedir}/lac
+
+ echo 'KERNEL=="icp_adf_ctl" MODE="0600"' > ${D}/etc/udev/rules.d/00-dh895xcc_qa.rules
+ echo 'KERNEL=="icp_dev[0-9]*" MODE="0600"' >> ${D}/etc/udev/rules.d/00-dh895xcc_qa.rules
+ echo 'KERNEL=="icp_dev_mem?" MODE="0600"' >> ${D}/etc/udev/rules.d/00-dh895xcc_qa.rules
+
+ install -m 640 ${ICP_ROOT}/${ICP_DH895X}/quickassist/include/*.h ${D}${includedir}
+ install -m 640 ${ICP_ROOT}/${ICP_DH895X}/quickassist/include/dc/*.h ${D}${includedir}
+ install -m 640 ${ICP_ROOT}/${ICP_DH895X}/quickassist/include/lac/*.h ${D}${includedir}
+ install -m 640 ${ICP_ROOT}/${ICP_DH895X}/quickassist/lookaside/access_layer/include/*.h ${D}${includedir}
+}
+
+PACKAGES += "${PN}-app"
+
+FILES_${PN}-dev = "\
+ ${includedir}/ \
+ "
+
+FILES_${PN} += "\
+ ${base_libdir}/firmware/ \
+ ${sysconfdir}/ \
+ ${sysconfdir}/udev/rules.d/ \
+ ${sysconfdir}/init.d/ \
+ ${libdir}/ \
+ "
+
+FILES_${PN}-dbg += "\
+ ${sysconfdir}/init.d/.debug \
+ "
+
+FILES_${PN}-app += "\
+ ${bindir}/* \
+ "
--
1.7.9.5
More information about the meta-intel
mailing list