[meta-intel] [PATCH] gstreamer-vaapi: add 0.5.6

[Ross Burton]

gstreamer-vaapi 0.5.x supports GStreamer 0.10/1.0/1.2, so add seperate recipes
for 0.10 and 1.0 builds.

This adds a new recipe name so keep the old gstreamer-vaapi_0.4.3 for now until
all users of that have migrated away.

Signed-off-by: Ross Burton <ross.burton at intel.com>
---
 .../gstreamer/gstreamer-vaapi-0.10_0.5.6.bb        |    7 ++++
 .../gstreamer/gstreamer-vaapi-1.0_0.5.6.bb         |    5 +++
 .../gstreamer/gstreamer-vaapi.inc                  |   41 ++++++++++++++++++++
 .../gstreamer/gstreamer-vaapi/install-tests.patch  |   31 +++++++++++++++
 .../gstreamer-vaapi/wayland-compile.patch          |   17 ++++++++
 5 files changed, 101 insertions(+)
 create mode 100644 common/recipes-multimedia/gstreamer/gstreamer-vaapi-0.10_0.5.6.bb
 create mode 100644 common/recipes-multimedia/gstreamer/gstreamer-vaapi-1.0_0.5.6.bb
 create mode 100644 common/recipes-multimedia/gstreamer/gstreamer-vaapi.inc
 create mode 100644 common/recipes-multimedia/gstreamer/gstreamer-vaapi/install-tests.patch
 create mode 100644 common/recipes-multimedia/gstreamer/gstreamer-vaapi/wayland-compile.patch

diff --git a/common/recipes-multimedia/gstreamer/gstreamer-vaapi-0.10_0.5.6.bb b/common/recipes-multimedia/gstreamer/gstreamer-vaapi-0.10_0.5.6.bb
new file mode 100644
index 0000000..784e0c5
--- /dev/null
+++ b/common/recipes-multimedia/gstreamer/gstreamer-vaapi-0.10_0.5.6.bb
@@ -0,0 +1,7 @@
+require gstreamer-vaapi.inc
+
+DEPENDS += "gstreamer gst-plugins-base gst-plugins-bad"
+
+SRC_URI += "file://wayland-compile.patch"
+
+GST_API_VERSION = "0.10"
diff --git a/common/recipes-multimedia/gstreamer/gstreamer-vaapi-1.0_0.5.6.bb b/common/recipes-multimedia/gstreamer/gstreamer-vaapi-1.0_0.5.6.bb
new file mode 100644
index 0000000..b8ad2a5
--- /dev/null
+++ b/common/recipes-multimedia/gstreamer/gstreamer-vaapi-1.0_0.5.6.bb
@@ -0,0 +1,5 @@
+require gstreamer-vaapi.inc
+
+DEPENDS += "gstreamer1.0 gstreamer1.0-plugins-base gstreamer1.0-plugins-bad"
+
+GST_API_VERSION = "1.0"
diff --git a/common/recipes-multimedia/gstreamer/gstreamer-vaapi.inc b/common/recipes-multimedia/gstreamer/gstreamer-vaapi.inc
new file mode 100644
index 0000000..9fc3248
--- /dev/null
+++ b/common/recipes-multimedia/gstreamer/gstreamer-vaapi.inc
@@ -0,0 +1,41 @@
+SUMMARY = "VA-API support to GStreamer"
+DESCRIPTION = "gstreamer-vaapi consists of a collection of VA-API \
+based plugins for GStreamer and helper libraries: `vaapidecode', \
+`vaapiconvert', and `vaapisink'."
+
+REALPN = "gstreamer-vaapi"
+FILESPATH = "${@base_set_filespath(["${FILE_DIRNAME}/${REALPN}", "${FILE_DIRNAME}/${REALPN}"], d)}"
+
+LICENSE = "LGPLv2.1+"
+LIC_FILES_CHKSUM = "file://COPYING.LIB;md5=4fbd65380cdd255951079008b364516c"
+
+DEPENDS = "libva"
+
+SRC_URI = "http://www.freedesktop.org/software/vaapi/releases/${REALPN}/${REALPN}-${PV}.tar.bz2 \
+           file://install-tests.patch"
+
+SRC_URI[md5sum] = "7b1ede7193bc5a0aca921c490684f7b5"
+SRC_URI[sha256sum] = "68e0598456fe17085f6b8b1ce3da066322cc02c363955fb319776a5404d2b0da"
+
+S = "${WORKDIR}/${REALPN}-${PV}"
+
+inherit autotools pkgconfig gtk-doc
+
+PACKAGES =+ "${PN}-tests"
+
+EXTRA_OECONF += "--with-gstreamer-api=${GST_API_VERSION}"
+
+PACKAGECONFIG ??= "drm \
+                   ${@base_contains("DISTRO_FEATURES", "opengl x11", "glx", "", d)} \
+                   ${@base_contains("DISTRO_FEATURES", "wayland", "wayland", "", d)} \
+                   ${@base_contains("DISTRO_FEATURES", "x11", "x11", "", d)}"
+
+PACKAGECONFIG[drm] = "--enable-drm,--disable-drm,udev libdrm"
+PACKAGECONFIG[glx] = "--enable-glx,--disable-glx,virtual/mesa"
+PACKAGECONFIG[wayland] = "--enable-wayland,--disable-wayland,wayland"
+PACKAGECONFIG[x11] = "--enable-x11,--disable-x11,virtual/libx11 libxrandr libxrender"
+
+FILES_${PN} += "${libdir}/gstreamer-*/*.so"
+FILES_${PN}-dbg += "${libdir}/gstreamer-*/.debug"
+FILES_${PN}-dev += "${libdir}/gstreamer-*/*.la ${libdir}/gstreamer-*/*.a"
+FILES_${PN}-tests = "${bindir}/*"
diff --git a/common/recipes-multimedia/gstreamer/gstreamer-vaapi/install-tests.patch b/common/recipes-multimedia/gstreamer/gstreamer-vaapi/install-tests.patch
new file mode 100644
index 0000000..9281b04
--- /dev/null
+++ b/common/recipes-multimedia/gstreamer/gstreamer-vaapi/install-tests.patch
@@ -0,0 +1,31 @@
+Install tests.
+
+Upstream-Status: Inappropriate
+Signed-off-by: Ross Burton <ross.burton at intel.com>
+
+---
+ tests/Makefile.am |    4 ++--
+ 1 file changed, 2 insertions(+), 2 deletions(-)
+
+diff --git a/tests/Makefile.am b/tests/Makefile.am
+index 2e7f191..8f65446 100644
+--- a/tests/Makefile.am
++++ b/tests/Makefile.am
+@@ -1,4 +1,4 @@
+-noinst_PROGRAMS = \
++bin_PROGRAMS = \
+ 	simple-decoder			\
+ 	test-decode			\
+ 	test-display			\
+@@ -9,7 +9,7 @@ noinst_PROGRAMS = \
+ 	$(NULL)
+ 
+ if USE_GLX
+-noinst_PROGRAMS += \
++bin_PROGRAMS += \
+ 	test-textures			\
+ 	$(NULL)
+ endif
+-- 
+1.7.10.4
+
diff --git a/common/recipes-multimedia/gstreamer/gstreamer-vaapi/wayland-compile.patch b/common/recipes-multimedia/gstreamer/gstreamer-vaapi/wayland-compile.patch
new file mode 100644
index 0000000..c42e01f
--- /dev/null
+++ b/common/recipes-multimedia/gstreamer/gstreamer-vaapi/wayland-compile.patch
@@ -0,0 +1,17 @@
+Fix compilation of the Wayland backend when using GStreamer 0.10.
+
+Upstream-Status: Submitted (https://bugzilla.gnome.org/show_bug.cgi?id=712282)
+Signed-off-by: Ross Burton <ross.burton at intel.com>
+
+diff --git a/gst-libs/gst/vaapi/Makefile.am b/gst-libs/gst/vaapi/Makefile.am
+index ab605e1..0a3fa38 100644
+--- a/gst-libs/gst/vaapi/Makefile.am
++++ b/gst-libs/gst/vaapi/Makefile.am
+@@ -364,6 +364,7 @@ libgstvaapi_wayland_ at GST_API_VERSION@_la_CFLAGS = \
+ 	-I$(top_srcdir)/gst-libs		\
+ 	$(GLIB_CFLAGS)				\
+ 	$(GST_BASE_CFLAGS)			\
++	$(top_builddir)/gst-libs/gst/video/libgstvaapi-videoutils.la \
+ 	$(WAYLAND_CFLAGS)			\
+ 	$(LIBVA_WAYLAND_CFLAGS)			\
+ 	$(NULL)
-- 
1.7.10.4