[meta-freescale] [PATCH v3 22/43] imx-atf: Add new package ARM Trusted Firmware

[Tom Hochstein]

Signed-off-by: Tom Hochstein <tom.hochstein at nxp.com>
---
 recipes-bsp/imx-atf/imx-atf_1.4.1.bb | 65 ++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 recipes-bsp/imx-atf/imx-atf_1.4.1.bb

diff --git a/recipes-bsp/imx-atf/imx-atf_1.4.1.bb b/recipes-bsp/imx-atf/imx-atf_1.4.1.bb
new file mode 100644
index 0000000..9bd9d73
--- /dev/null
+++ b/recipes-bsp/imx-atf/imx-atf_1.4.1.bb
@@ -0,0 +1,65 @@
+# Copyright 2017-2018 NXP
+
+DESCRIPTION = "i.MX ARM Trusted Firmware"
+SECTION = "BSP"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/BSD-3-Clause;md5=550794465ba0ec5312d6919e203a55f9"
+
+PV = "1.4.1+git${SRCPV}"
+
+SRCBRANCH = "imx_4.9.88_imx8qxp_beta2"
+SRC_URI = "git://source.codeaurora.org/external/imx/imx-atf.git;protocol=https;branch=${SRCBRANCH}"
+SRCREV = "00b653ec4b51a211ae735ffe0d3c9de7a8979947"
+
+S = "${WORKDIR}/git"
+
+inherit pkgconfig deploy
+
+BOOT_TOOLS = "imx-boot-tools"
+
+SOC_ATF ?= "imx8qm"
+SOC_ATF_mx8qm = "imx8qm"
+SOC_ATF_mx8qxp = "imx8qxp"
+SOC_ATF_mx8mq = "imx8mq"
+
+SYSROOT_DIRS += "/boot"
+
+EXTRA_OEMAKE_append = " ${@bb.utils.contains('COMBINED_FEATURES', 'optee', 'SPD=opteed', '', d)}"
+
+do_compile () {
+    export CROSS_COMPILE="${TARGET_PREFIX}"
+    cd ${S}
+    # Clear LDFLAGS to avoid the option -Wl recognize issue
+    unset LDFLAGS
+
+    echo "-> Build ${SOC_ATF} bl31.bin"
+    # Set BUIL_STRING with the revision info
+    BUILD_STRING=""
+    if [ -e ${S}/.revision ]; then
+        cur_rev=`cat ${S}/.revision`
+        echo " Current revision is ${cur_rev} ."
+        BUILD_STRING="BUILD_STRING=${cur_rev}"
+    else
+        echo " No .revision found! "
+    fi
+    oe_runmake clean PLAT=${SOC_ATF}
+    oe_runmake ${BUILD_STRING} PLAT=${SOC_ATF} bl31
+
+    unset CROSS_COMPILE
+}
+
+do_deploy () {
+    install -d ${DEPLOYDIR}/${BOOT_TOOLS}
+    install -m 0644 ${S}/build/${SOC_ATF}/release/bl31.bin ${DEPLOYDIR}/${BOOT_TOOLS}/bl31-${SOC_ATF}.bin
+}
+addtask deploy before do_install after do_compile
+
+do_install () {
+    install -d ${D}/boot
+    install -m 0644 ${S}/build/${SOC_ATF}/release/bl31.bin ${D}/boot/bl31-${SOC_ATF}.bin
+}
+
+FILES_${PN} = "/boot"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE = "(mx8)"
-- 
2.7.4