[meta-freescale] [PATCH v2 24/43] imx-sc-firmware: Add new package System Controller Firmware

[Tom Hochstein]

Add System Controller firmware package for i.MX 8 and 8X families.

Signed-off-by: Tom Hochstein <tom.hochstein at nxp.com>
---
 recipes-bsp/imx-sc-firmware/imx-sc-firmware_0.7.bb | 50 ++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 recipes-bsp/imx-sc-firmware/imx-sc-firmware_0.7.bb

diff --git a/recipes-bsp/imx-sc-firmware/imx-sc-firmware_0.7.bb b/recipes-bsp/imx-sc-firmware/imx-sc-firmware_0.7.bb
new file mode 100644
index 0000000..c203d7e
--- /dev/null
+++ b/recipes-bsp/imx-sc-firmware/imx-sc-firmware_0.7.bb
@@ -0,0 +1,50 @@
+# Copyright (C) 2016 Freescale Semiconductor
+# Copyright 2017-2018 NXP
+
+DESCRIPTION = "i.MX System Controller Firmware"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=ab61cab9599935bfe9f700405ef00f28"
+SECTION = "BSP"
+
+inherit fsl-eula-unpack pkgconfig deploy
+
+SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.bin;fsl-eula=true"
+
+SRC_URI[md5sum] = "9dcdbdae491bd6b027ccab0e354870cb"
+SRC_URI[sha256sum] = "46e487605c31f44b4fe0280e57e4e0a3fe51c375300766805ae1161c39021766"
+
+S = "${WORKDIR}/${PN}-${PV}"
+
+BOARD_TYPE ?= "mek"
+SC_FIRMWARE_NAME ?= "mx8qm-mek-scfw-tcm.bin"
+SC_FIRMWARE_NAME_mx8qm = "mx8qm-${BOARD_TYPE}-scfw-tcm.bin"
+SC_FIRMWARE_NAME_mx8qxp = "mx8qx-${BOARD_TYPE}-scfw-tcm.bin"
+symlink_name = "scfw_tcm.bin"
+
+SYSROOT_DIRS += "/boot"
+
+do_install () {
+    install -d ${D}/boot
+    install -m 0644 ${S}/${SC_FIRMWARE_NAME} ${D}/boot/
+}
+
+BOOT_TOOLS = "imx-boot-tools"
+
+do_deploy () {
+    install -d ${DEPLOYDIR}/${BOOT_TOOLS}
+    install -m 0644 ${S}/${SC_FIRMWARE_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}/
+    cd ${DEPLOYDIR}/${BOOT_TOOLS}/
+    rm -f ${symlink_name}
+    ln -sf ${SC_FIRMWARE_NAME} ${symlink_name}
+    cd -
+}
+
+addtask deploy after do_install
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+FILES_${PN} = "/boot"
+
+COMPATIBLE_MACHINE = "(mx8qm|mx8qxp)"
-- 
2.7.4