[meta-freescale] [PATCH 17/29] linux-qoriq: update to v4.9

[Otavio Salvador]

On Thu, Sep 28, 2017 at 2:33 AM, Chunrong Guo <B40290 at freescale.com> wrote:
> From: Chunrong Guo <chunrong.guo at nxp.com>
>
> Signed-off-by: Chunrong Guo <chunrong.guo at nxp.com>
> ---
>  recipes-kernel/linux/linux-qoriq_4.9.bb | 78 +++++++++++++++++++++++++++++++++
>  1 file changed, 78 insertions(+)
>  create mode 100644 recipes-kernel/linux/linux-qoriq_4.9.bb
>
> diff --git a/recipes-kernel/linux/linux-qoriq_4.9.bb b/recipes-kernel/linux/linux-qoriq_4.9.bb
> new file mode 100644
> index 0000000..c434c34
> --- /dev/null
> +++ b/recipes-kernel/linux/linux-qoriq_4.9.bb
> @@ -0,0 +1,78 @@
> +inherit kernel qoriq_build_64bit_kernel
> +inherit fsl-kernel-localversion
> +
> +SUMMARY = "Linux Kernel for Freescale QorIQ platforms"
> +SECTION = "kernel"
> +LICENSE = "GPLv2"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
> +
> +SRC_URI = "git://github.com/qoriq-open-source/linux.git;nobranch=1 \
> +"
> +SRCREV = "f5edd990c1ed7844032db171e72a2d71cfc4712c"
> +
> +S = "${WORKDIR}/git"
> +
> +DEPENDS_append = " libgcc"
> +# not put Images into /boot of rootfs, install kernel-image if needed
> +RDEPENDS_kernel-base = ""
> +
> +KERNEL_CC_append = " ${TOOLCHAIN_OPTIONS}"
> +KERNEL_LD_append = " ${TOOLCHAIN_OPTIONS}"
> +KERNEL_EXTRA_ARGS += "LOADADDR=${UBOOT_ENTRYPOINT}"
> +
> +ZIMAGE_BASE_NAME = "zImage-${PKGE}-${PKGV}-${PKGR}-${MACHINE}-${DATETIME}"
> +ZIMAGE_BASE_NAME[vardepsexclude] = "DATETIME"
> +
> +SCMVERSION ?= "y"
> +LOCALVERSION = ""
> +DELTA_KERNEL_DEFCONFIG ?= ""
> +DELTA_KERNEL_DEFCONFIG_prepend_qoriq-arm64 = "lsdk.config "
> +DELTA_KERNEL_DEFCONFIG_prepend_fsl-lsch2-32b = "multi_v7_lpae.config lsdk.config multi_v8.config "
> +DELTA_KERNEL_DEFCONFIG_prepend_ls102xa = "multi_v7_lpae.config lsdk.config "
> +
> +do_merge_delta_config() {
> +    # copy desired defconfig so we pick it up for the real kernel_do_configure
> +    cp ${KERNEL_DEFCONFIG} .config
> +
> +    # add config fragments
> +    for deltacfg in ${DELTA_KERNEL_DEFCONFIG}; do
> +        if [ -f "${deltacfg}" ]; then
> +            ${S}/scripts/kconfig/merge_config.sh -m .config ${deltacfg}
> +        elif [ -f "${WORKDIR}/${deltacfg}" ]; then
> +            ${S}/scripts/kconfig/merge_config.sh -m .config ${WORKDIR}/${deltacfg}
> +        elif [ -f "${S}/arch/${ARCH}/configs/${deltacfg}" ]; then
> +            ${S}/scripts/kconfig/merge_config.sh -m .config \
> +                ${S}/arch/${ARCH}/configs/${deltacfg}
> +        fi
> +    done
> +    cp .config ${WORKDIR}/defconfig
> +}
> +addtask merge_delta_config before do_preconfigure after do_patch
> +
> +# The link of dts folder is needed for 32b compile of aarch64 targets(e.g. ls1043ardb-32b)
> +do_compile_prepend_fsl-lsch2-32b() {
> +    ln -sfT ${STAGING_KERNEL_DIR}/arch/arm64/boot/dts/freescale ${STAGING_KERNEL_DIR}/arch/arm/boot/dts/freescale
> +}
> +
> +do_install_prepend_fsl-lsch2-32b() {
> +    rm -f ${STAGING_KERNEL_DIR}/arch/arm/boot/dts/freescale
> +}

Couldn't this be handled on the kernel build system itself?

> +do_install_append_qoriq-arm() {
> +    install -m 0644 arch/${ARCH}/boot/zImage ${D}/boot/zImage-${KERNEL_VERSION}
> +    ln -sf zImage-${KERNEL_VERSION} ${D}/boot/zImage
> +}
> +
> +do_deploy_append_qoriq-arm64() {
> +    if [ -f ${DEPLOYDIR}/fsl-ls1043a-rdb-sdk.dtb ]; then
> +        mv fsl-ls1043a-rdb-sdk.dtb fsl-ls1043a-rdb.dtb
> +        mv  Image-fsl-ls1043a-rdb-sdk.dtb Image-fsl-ls1043a-rdb.dtb
> +    fi
> +    if [ -f ${DEPLOYDIR}/fsl-ls1046a-rdb-sdk.dtb ]; then
> +        mv fsl-ls1046a-rdb-sdk.dtb fsl-ls1046a-rdb.dtb
> +        mv Image-fsl-ls1046a-rdb-sdk.dtb Image-fsl-ls1046a-rdb.dtb
> +    fi
> +}

Device tree should use right name on kernel.

> +FILES_kernel-image += "/boot/zImage*"
> +COMPATIBLE_MACHINE = "(qoriq)"
> --
> 1.9.0
>
> --
> _______________________________________________
> meta-freescale mailing list
> meta-freescale at yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-freescale



-- 
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854            Mobile: +1 (347) 903-9750