[meta-freescale] [3rdparty][PATCH v2 2/2] u-boot-boundary-fw-utils: Add recipe for version 2016.03

[Fabio Berton]

Signed-off-by: Fabio Berton <fabio.berton at ossystems.com.br>
---
 .../u-boot/u-boot-boundary-fw-utils/fw_env.config  |  1 +
 .../u-boot/u-boot-boundary-fw-utils_2016.03.bb     | 38 ++++++++++++++++++++++
 2 files changed, 39 insertions(+)
 create mode 100644 recipes-bsp/u-boot/u-boot-boundary-fw-utils/fw_env.config
 create mode 100644 recipes-bsp/u-boot/u-boot-boundary-fw-utils_2016.03.bb

diff --git a/recipes-bsp/u-boot/u-boot-boundary-fw-utils/fw_env.config b/recipes-bsp/u-boot/u-boot-boundary-fw-utils/fw_env.config
new file mode 100644
index 0000000..571e829
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-boundary-fw-utils/fw_env.config
@@ -0,0 +1 @@
+/dev/mtd1   0x00000 0x2000  0x1000  2
diff --git a/recipes-bsp/u-boot/u-boot-boundary-fw-utils_2016.03.bb b/recipes-bsp/u-boot/u-boot-boundary-fw-utils_2016.03.bb
new file mode 100644
index 0000000..2f8c75e
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-boundary-fw-utils_2016.03.bb
@@ -0,0 +1,38 @@
+require u-boot-boundary-common_${PV}.inc
+
+SUMMARY = "U-Boot bootloader fw_printenv/setenv utilities"
+DEPENDS = "mtd-utils"
+
+SRC_URI += "file://fw_env.config"
+
+INSANE_SKIP_${PN} = "already-stripped"
+EXTRA_OEMAKE_class-target = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" V=1'
+EXTRA_OEMAKE_class-cross = 'ARCH=${TARGET_ARCH} CC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
+
+inherit uboot-config
+
+do_compile () {
+    oe_runmake ${UBOOT_MACHINE}
+    oe_runmake env
+}
+
+do_install () {
+    install -Dm 0755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_printenv
+    install -Dm 0755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_setenv
+    install -Dm 0644 ${WORKDIR}/fw_env.config   ${D}${sysconfdir}/fw_env.config
+}
+
+do_install_class-cross () {
+    install -d ${D}${bindir_cross}
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_printenv
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_setenv
+}
+
+SYSROOT_PREPROCESS_FUNCS_class-cross = "uboot_fw_utils_cross"
+uboot_fw_utils_cross() {
+    sysroot_stage_dir ${D}${bindir_cross} ${SYSROOT_DESTDIR}${bindir_cross}
+}
+
+RPROVIDES_${PN} += "u-boot-fw-utils"
+
+BBCLASSEXTEND = "cross"
-- 
2.14.2