[meta-freescale] [distro][PATCH 1/2] distro/fslc: Add initial distro settings

[Fabio Berton]

Freescale Community Distro support four flavors:

  - fslc-framebuffer: Distro for Framebuffer graphical backend. This
    distro doesn't include x11 and wayland features.

  - fslc-wayland: Distro for Wayland without X11. This distro include
    wayland feature but doesn't has x11 support.

  - fslc-x11: Distro for X11 without wayland. This distro include x11
    feature and doesn' has wayland support.

  - fslc-xwayland: Distro for Wayland with X11. This distro include
    both wayland and x11 features.

These four distros are based on Poky Yocto Project Reference Distro.

Signed-off-by: Fabio Berton <fabio.berton at ossystems.com.br>
---
 conf/distro/fslc-framebuffer.conf |  9 ++++++++
 conf/distro/fslc-wayland.conf     | 10 +++++++++
 conf/distro/fslc-x11.conf         | 12 +++++++++++
 conf/distro/fslc-xwayland.conf    | 10 +++++++++
 conf/distro/include/fslc-base.inc | 44 +++++++++++++++++++++++++++++++++++++++
 5 files changed, 85 insertions(+)
 create mode 100644 conf/distro/fslc-framebuffer.conf
 create mode 100644 conf/distro/fslc-wayland.conf
 create mode 100644 conf/distro/fslc-x11.conf
 create mode 100644 conf/distro/fslc-xwayland.conf
 create mode 100644 conf/distro/include/fslc-base.inc

diff --git a/conf/distro/fslc-framebuffer.conf b/conf/distro/fslc-framebuffer.conf
new file mode 100644
index 0000000..f9031a7
--- /dev/null
+++ b/conf/distro/fslc-framebuffer.conf
@@ -0,0 +1,9 @@
+# FSLC Distro for FrameBuffer graphical backend.
+
+require conf/distro/include/fslc-base.inc
+
+DISTRO = "fslc-framebuffer"
+DISTRO_NAME = "FSLC FrameBuffer"
+
+# Remove conflicting backends.
+DISTRO_FEATURES_remove = "x11 wayland directfb "
diff --git a/conf/distro/fslc-wayland.conf b/conf/distro/fslc-wayland.conf
new file mode 100644
index 0000000..9114621
--- /dev/null
+++ b/conf/distro/fslc-wayland.conf
@@ -0,0 +1,10 @@
+# FSLC Distro for Wayland without X11.
+
+require conf/distro/include/fslc-base.inc
+
+DISTRO = "fslc-wayland"
+DISTRO_NAME = "FSLC Wayland"
+
+# Remove conflicting backends
+DISTRO_FEATURES_remove = "directfb x11 "
+DISTRO_FEATURES_append = " wayland"
diff --git a/conf/distro/fslc-x11.conf b/conf/distro/fslc-x11.conf
new file mode 100644
index 0000000..dac7609
--- /dev/null
+++ b/conf/distro/fslc-x11.conf
@@ -0,0 +1,12 @@
+# FSLC Distro for X11 without wayland.
+
+require conf/distro/include/fslc-base.inc
+
+DISTRO = "fslc-x11"
+DISTRO_NAME = "FSLC X11"
+
+# Remove conflicting backends.
+DISTRO_FEATURES_remove = "wayland "
+
+# These are X11 specific
+DISTRO_FEATURES_append = " x11"
diff --git a/conf/distro/fslc-xwayland.conf b/conf/distro/fslc-xwayland.conf
new file mode 100644
index 0000000..ff7a744
--- /dev/null
+++ b/conf/distro/fslc-xwayland.conf
@@ -0,0 +1,10 @@
+# FSLC Distro for Wayland with X11.
+
+require conf/distro/include/fslc-base.inc
+
+DISTRO = "fslc-xwayland"
+DISTRO_NAME = "FSLC Wayland X11"
+
+# Remove conflicting backends
+DISTRO_FEATURES_remove = "directfb "
+DISTRO_FEATURES_append = " x11 wayland"
diff --git a/conf/distro/include/fslc-base.inc b/conf/distro/include/fslc-base.inc
new file mode 100644
index 0000000..b9d08bb
--- /dev/null
+++ b/conf/distro/include/fslc-base.inc
@@ -0,0 +1,44 @@
+require conf/distro/poky.conf
+
+DISTRO = "fslc-base"
+DISTRO_NAME = "FSLC Distro Base"
+SDK_VENDOR = "-fslcsdk"
+
+MAINTAINER = "FSL Community Team <meta-freescale at yoctoproject.org>"
+
+TARGET_VENDOR = "-fslc"
+
+DISTROOVERRIDES = "fslc"
+
+# This function changes the default tune for machines which are based on armv7a
+# to use common tune value
+def arm_tune_handler(d):
+    features = d.getVar('TUNE_FEATURES', True).split()
+    if 'armv7a' in features or 'armv7ve' in features:
+        tune = 'armv7athf'
+        if 'bigendian' in features:
+            tune += 'b'
+        if 'vfpv3' in features:
+            tune += '-vfpv3'
+        if 'vfpv3d16' in features:
+            tune += '-vfpv3d16'
+        if 'neon' in features:
+            tune += '-neon'
+        if 'vfpv4' in features:
+            tune += '-vfpv4'
+    else:
+        tune = d.getVar('DEFAULTTUNE', True)
+    return tune
+
+DEFAULTTUNE_fslc := "${@arm_tune_handler(d)}"
+
+DISTRO_ARM_INSTRUCTION ?= "thumb"
+DISTRO_ARM_INSTRUCTION_armv5 ?= "arm"
+ARM_INSTRUCTION_SET_fslc ??= "${DISTRO_ARM_INSTRUCTION}"
+
+# Log information on images and packages
+INHERIT += "buildhistory"
+BUILDHISTORY_COMMIT = "1"
+
+# Use bluez5 as default.
+DISTRO_FEATURES_append = " bluez5"
-- 
2.1.4