[meta-freescale] [meta-fsl-demos PATCH v2 1/3] packagegroup-fsl-tools-audio: Add recipe

[Otavio Salvador]

From: Ann Thornton <ra43240 at freescale.com>

The package group is used to provide an easy way to install the audio
tools for either pulseaudio or alsa based distributions.

Signed-off-by: Ann Thornton <ra43240 at freescale.com>
Signed-off-by: Otavio Salvador <otavio at ossystems.com.br>
---

Changes in v2:
- Refactor the recipe
- Rework commit log
- Improve summary

 .../packagegroups/packagegroup-fsl-tools-audio.bb  | 33 ++++++++++++++++++++++
 1 file changed, 33 insertions(+)
 create mode 100644 recipes-fsl/packagegroups/packagegroup-fsl-tools-audio.bb

diff --git a/recipes-fsl/packagegroups/packagegroup-fsl-tools-audio.bb b/recipes-fsl/packagegroups/packagegroup-fsl-tools-audio.bb
new file mode 100644
index 0000000..14060d1
--- /dev/null
+++ b/recipes-fsl/packagegroups/packagegroup-fsl-tools-audio.bb
@@ -0,0 +1,33 @@
+# Copyright (C) 2015 Freescale Semiconductor
+# Copyright (C) 2015 O.S. Systems Software LTDA.
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+SUMMARY = "Set of audio tools for inclusion on images"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=3f40d7994397109285ec7b81fdeb3b58 \
+                    file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+inherit packagegroup
+
+ALSA_INSTALL = " \
+    alsa-utils \
+    alsa-tools \
+"
+
+PULSEAUDIO_INSTALL = " \
+    pulseaudio-server \
+    pulseaudio-module-cli \
+    pulseaudio-misc \
+    pulseaudio-module-device-manager \
+    ${@bb.utils.contains("DISTRO_FEATURES", "x11", "pulseaudio-module-x11-xsmp \
+                                                    pulseaudio-module-x11-publish \
+                                                    pulseaudio-module-x11-cork-request \
+                                                    pulseaudio-module-x11-bell \
+                                                    consolekit", \
+                                            "", d)} \
+"
+
+RDEPENDS_${PN} = " \
+    ${@bb.utils.contains("DISTRO_FEATURES", "alsa",  "${ALSA_INSTALL}", "", d)} \
+    ${@bb.utils.contains("DISTRO_FEATURES", "pulseaudio",  "${PULSEAUDIO_INSTALL}", "", d)} \
+"
-- 
2.6.1