[meta-freescale] [meta-fsl-demos][PATCH v2 9/9] fsl-image-gui: Create Freescale Image Recipe

[Daiane Angolini]

On Thu, Jul 16, 2015 at 4:23 PM, Lauren Post <lauren.post at freescale.com> wrote:
> Create the image recipe supporting the i.MX releases.
> This integrates the Freescale Gstreamer 1.0 plugin,
> tools and graphics features used by testing the
> Freescale i.MX BSP Releases for all backends.

I was not able to figure out the differences between v1 and v2, and I
was not able to understand if Gary's comment was included or answered.

I still don't see the need of a new image

Daiane

>
> Signed-off-by: Lauren Post <lauren.post at freescale.com>
> ---
>  recipes-fsl/images/fsl-image-gui.bb |   70 +++++++++++++++++++++++++++++++++++
>  1 file changed, 70 insertions(+)
>  create mode 100644 recipes-fsl/images/fsl-image-gui.bb
>
> diff --git a/recipes-fsl/images/fsl-image-gui.bb b/recipes-fsl/images/fsl-image-gui.bb
> new file mode 100644
> index 0000000..568552e
> --- /dev/null
> +++ b/recipes-fsl/images/fsl-image-gui.bb
> @@ -0,0 +1,70 @@
> +DESCRIPTION = "Freescale Image"
> +LICENSE = "MIT"
> +
> +inherit core-image
> +
> +IMAGE_FEATURES += " splash"
> +IMAGE_FEATURES += "${@base_contains('DISTRO_FEATURES', 'x11', \
> +                    ' package-management x11-base x11-sato hwcodecs', '', d)}"
> +IMAGE_FEATURES += "${@base_contains('DISTRO_FEATURES', 'wayland', \
> +                      base_contains('DISTRO_FEATURES', 'x11', '', \
> +                    ' package-management hwcodecs', d), '', d)}"
> +
> +X11_EXTRA_IMAGE_FEATURES ?= "${@base_contains('DISTRO_FEATURES', 'x11', \
> +    'tools-testapps', '', d)}"
> +
> +# Add extra image features
> +EXTRA_IMAGE_FEATURES += " \
> +    ${X11_EXTRA_IMAGE_FEATURES} \
> +    nfs-server \
> +    tools-debug \
> +    tools-profile \
> +    ssh-server-dropbear \
> +    "
> +
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +
> +# Backend-specific packages
> +# Direct FB packages
> +DFB_IMAGE_INSTALL = "${@base_contains('DISTRO_FEATURES', 'directfb', \
> +    'packagegroup-core-full-cmdline packagegroup-core-directfb', '', d)}"
> +
> +# Wayland packages
> +WAYLAND_IMAGE_INSTALL = "${@base_contains('DISTRO_FEATURES', 'wayland', \
> +    base_contains('DISTRO_FEATURES', 'x11', '', \
> +    'weston weston-init weston-examples', d), '', d)}"
> +WAYLAND_IMAGE_INSTALL_mx6 = "${@base_contains('DISTRO_FEATURES', 'wayland', \
> +    base_contains('DISTRO_FEATURES', 'x11', '', \
> +    'gtk+3-demo clutter-1.0-examples', d), '', d)}"
> +WAYLAND_IMAGE_INSTALL_remove_mx6sl = "clutter-1.0-examples"
> +
> +# X11 packages
> +X11_INSTALL = "${@base_contains('DISTRO_FEATURES', 'x11', \
> +   'packagegroup-core-x11-sato-games \
> +    packagegroup-fsl-pulseaudio \
> +    xorg-minimal-fonts \
> +    liberation-fonts', '', d)}"
> +
> +X11_IMAGE_INSTALL = ""
> +X11_IMAGE_INSTALL_mx6 = "${X11_INSTALL}"
> +X11_IMAGE_INSTALL_mx7 = "${X11_INSTALL}"
> +X11_IMAGE_INSTALL_append_mx6sl = " libopenvg-mx6"
> +
> +# set mm image install specific to SOC
> +MM_IMAGE_INSTALL = ""
> +MM_IMAGE_INSTALL_mx6 = "packagegroup-fsl-gstreamer1.0"
> +MM_IMAGE_INSTALL_mx7 = "packagegroup-fsl-gstreamer1.0"
> +
> +IMAGE_INSTALL += " \
> +    ${X11_IMAGE_INSTALL} \
> +    ${DFB_IMAGE_INSTALL} \
> +    ${WAYLAND_IMAGE_INSTALL} \
> +    ${MM_IMAGE_INSTALL} \
> +    packagegroup-fsl-tools-bluetooth \
> +    packagegroup-fsl-tools-gpu \
> +    packagegroup-fsl-tools-gpu-external \
> +    packagegroup-fsl-tools-testapps \
> +    packagegroup-fsl-tools-benchmark \
> +    "
> +
> +export IMAGE_BASENAME = "fsl-image-gui"
> --
> 1.7.9.5
>
> --
> _______________________________________________
> meta-freescale mailing list
> meta-freescale at yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-freescale