[meta-freescale] [meta-fsl-ppc][PATCH 3/3] dpa-offload: add recipe
b28495 at freescale.com
b28495 at freescale.com
Fri Jul 17 02:29:03 PDT 2015
From: Ting Liu <ting.liu at freescale.com>
The user space DPAA offloading drivers were splited from the old usdpaa.
Signed-off-by: Ting Liu <ting.liu at freescale.com>
---
recipes-dpaa/dpa-offload/dpa-offload_git.bb | 49 +++++++++++++++++++++++++++++
1 file changed, 49 insertions(+)
create mode 100644 recipes-dpaa/dpa-offload/dpa-offload_git.bb
diff --git a/recipes-dpaa/dpa-offload/dpa-offload_git.bb b/recipes-dpaa/dpa-offload/dpa-offload_git.bb
new file mode 100644
index 0000000..73809e2
--- /dev/null
+++ b/recipes-dpaa/dpa-offload/dpa-offload_git.bb
@@ -0,0 +1,49 @@
+DESCRIPTION = "Data-Path Acceleration Architecture Offloading User-Space Drivers"
+LICENSE = "BSD & GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=c03ebb7a330b209986517466c74da72c"
+
+inherit pkgconfig
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+DEPENDS = "usdpaa fmlib"
+DEPENDS_append_b4860qds = " ipc-ust"
+DEPENDS_append_b4420qds = " ipc-ust"
+
+RDEPENDS_${PN} = "libgcc bash"
+RDEPENDS_${PN}_append_b4860qds = " ipc-ust"
+RDEPENDS_${PN}_append_b4420qds = " ipc-ust"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/usdpaa/dpa-offload.git;nobranch=1"
+SRCREV = "ed6191db9439d1aaba27fc01238da770d1d8ef9e"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = 'CC="${CC}" LD="${LD}"'
+export ARCH="${TARGET_ARCH}"
+
+PARALLEL_MAKE_pn-${PN} = ""
+
+FMAN_VARIANT ?= "P4080"
+FMAN_VARIANT_b4 = "FMAN_V3H"
+FMAN_VARIANT_t1 = "FMAN_V3L"
+FMAN_VARIANT_t2 = "FMAN_V3H"
+FMAN_VARIANT_t4 = "FMAN_V3H"
+FMAN_VARIANT_p1023rdb = "P1023"
+
+do_compile_prepend () {
+ export USDPAA_CFLAGS="-I ${STAGING_INCDIR}/usdpaa"
+ export FMLIB_CFLAGS="-I ${STAGING_INCDIR}/fmd \
+ -I ${STAGING_INCDIR}/fmd/Peripherals \
+ -I ${STAGING_INCDIR}/fmd/integrations \
+ -D${FMAN_VARIANT} -DNCSW_LINUX"
+}
+
+do_install () {
+ oe_runmake install DESTDIR=${D}
+}
+
+ALLOW_EMPTY_${PN} = "1"
+
+COMPATIBLE_HOST_qoriq-ppc = ".*"
+COMPATIBLE_HOST ?= "(none)"
--
1.9.1
More information about the meta-freescale
mailing list