[meta-freescale] [meta-fsl-demos][PATCH 6/6] fsl-image-gui: Create Freescale Image Recipe

[Gary Thomas]

On 2015-07-11 08:50, Lauren Post wrote:
> Create the image recipe supporting the i.MX releases.
> This integrates the Freescale Gstreamer 1.0 plugin and
> tools used by testing the Freescale i.MX BSP Releases for
> all backends.
>
> Signed-off-by: Lauren Post <lauren.post at freescale.com>
> ---
>   recipes-fsl/images/fsl-image-gui.bb |   75 +++++++++++++++++++++++++++++++++++
>   1 file changed, 75 insertions(+)
>   create mode 100644 recipes-fsl/images/fsl-image-gui.bb
>
> diff --git a/recipes-fsl/images/fsl-image-gui.bb b/recipes-fsl/images/fsl-image-gui.bb
> new file mode 100644
> index 0000000..0f0c9cc
> --- /dev/null
> +++ b/recipes-fsl/images/fsl-image-gui.bb
> @@ -0,0 +1,75 @@
> +DESCRIPTION = "Freescale Image"
> +LICENSE = "MIT"
> +
> +inherit core-image
> +# require recipes-fsl/images/fsl-image-multimedia.bb
> +
> +IMAGE_FEATURES += " splash"
> +IMAGE_FEATURES += "${@base_contains('DISTRO_FEATURES', 'x11', \
> +                            ' package-management x11-base x11-sato hwcodecs', '', d)}"
> +IMAGE_FEATURES += "${@base_contains('DISTRO_FEATURES', 'wayland', \
> +                            base_contains('DISTRO_FEATURES', 'x11', '', ' package-management hwcodecs', d), \
> +                            '', d)}"

This doesn't seem correct/necessary - if x11 is in DISTRO_FEATURES, then
these values will have been set in the previous line.

> +
> +X11_EXTRA_IMAGE_FEATURES ?= "${@base_contains('DISTRO_FEATURES', 'x11', \
> +    ' tools-testapps', '', d)}"
> +
> +# Add extra image features
> +EXTRA_IMAGE_FEATURES += " \
> +    ${X11_EXTRA_IMAGE_FEATURES} \
> +    nfs-server \
> +    tools-debug \
> +    tools-profile \
> +    ssh-server-dropbear \
> +    "
> +
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +
> +# Backend-specific packages
> +# Direct FB packages
> +DFB_INSTALL = "${@base_contains('DISTRO_FEATURES', 'directfb', \
> +    'packagegroup-core-full-cmdline packagegroup-core-directfb', '', d)}"
> +DFB_INSTALL_VIV = "${@base_contains('DISTRO_FEATURES', 'directfb', \
> +    'libvivante-dfb-mx6', '', d)}"
> +
> +DFB_IMAGE_INSTALL       = "${DFB_INSTALL}"
> +DFB_IMAGE_INSTALL_mx6q  = "${DFB_INSTALL} ${DFB_INSTALL_VIV}"
> +DFB_IMAGE_INSTALL_mx6dl = "${DFB_INSTALL} ${DFB_INSTALL_VIV}"
> +DFB_IMAGE_INSTALL_mx6sx = "${DFB_INSTALL} ${DFB_INSTALL_VIV}"
> +DFB_IMAGE_INSTALL_mx6sl = "${DFB_INSTALL} ${DFB_INSTALL_VIV}"
> +
> +# Wayland packages
> +WAYLAND_IMAGE_INSTALL = ""
> +WAYLAND_IMAGE_INSTALL_mx6 = "${@base_contains('DISTRO_FEATURES', 'wayland', \
> +    base_contains('DISTRO_FEATURES', 'x11', '', \
> +    ' weston weston-init weston-examples gtk+3-demo clutter-1.0-examples', d),\
> +    '', d)}"
> +WAYLAND_IMAGE_INSTALL_remove_mx6sl = "clutter-1.0-examples"

Again, this doesn't look right to me.  Aren't x11 and wayland mutually exclusive?

> +
> +# X11 packages
> +X11_IMAGE_INSTALL = ""
> +X11_IMAGE_INSTALL_append_mx6sl = " libopenvg-mx6"
> +
> +# Add in Graphics
> +X11_IMAGE_INSTALL_GRAPHICS = "${@base_contains('DISTRO_FEATURES', 'x11', \
> +   'packagegroup-core-x11-sato-games \
> +    xorg-minimal-fonts \
> +    liberation-fonts', '', d)}"
> +
> +# set mm image install specific to SOC
> +MM_IMAGE_INSTALL = ""
> +MM_IMAGE_INSTALL_mx6 = "packagegroup-fsl-gstreamer1.0"
> +MM_IMAGE_INSTALL_mx7 = "packagegroup-fsl-gstreamer1.0"
> +
> +IMAGE_INSTALL += " \
> +    ${X11_IMAGE_INSTALL} \
> +    ${X11_IMAGE_INSTALL_GRAPHICS} \
> +    ${DFB_IMAGE_INSTALL} \
> +    ${WAYLAND_IMAGE_INSTALL} \
> +    ${MM_IMAGE_INSTALL} \
> +    packagegroup-fsl-tools-gpu \
> +    packagegroup-fsl-tools-gpu-external \
> +    packagegroup-fsl-tools-testapps \
> +    packagegroup-fsl-tools-benchmark \
> +    "
> +export IMAGE_BASENAME = "fsl-image-gui"
>

-- 
------------------------------------------------------------
Gary Thomas                 |  Consulting for the
MLB Associates              |    Embedded world
------------------------------------------------------------