[meta-freescale] [meta-fsl-demos][PATCH 04/12] Add packagegroup-fsl-tools-audio.bb

[Ann Thornton]

This packagegroup adds pulseaudio and/or alsa audio tools if
pulseaudio or alsa have been included in the DISTRO features.
It also adds x11 tools only if x11 was specified in the DISTRO.
This simplifies the image recipe and makes it clearer.

Signed-off-by: Ann Thornton <ra43240 at freescale.com>
---
 .../packagegroups/packagegroup-fsl-tools-audio.bb  | 37 ++++++++++++++++++++++
 1 file changed, 37 insertions(+)
 create mode 100644 recipes-fsl/packagegroups/packagegroup-fsl-tools-audio.bb

diff --git a/recipes-fsl/packagegroups/packagegroup-fsl-tools-audio.bb b/recipes-fsl/packagegroups/packagegroup-fsl-tools-audio.bb
new file mode 100644
index 0000000..1e5fec1
--- /dev/null
+++ b/recipes-fsl/packagegroups/packagegroup-fsl-tools-audio.bb
@@ -0,0 +1,37 @@
+# Copyright (C) 2015 Freescale Semiconductor
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+SUMMARY = "Freescale Package group for audio tools"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=3f40d7994397109285ec7b81fdeb3b58 \
+                    file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+inherit packagegroup
+
+PACKAGES = "${PN}"
+
+PULSEAUDIO_X11_INSTALL = "${@base_contains('DISTRO_FEATURES','x11', \
+    'pulseaudio-module-x11-xsmp \
+     pulseaudio-module-x11-publish \
+     pulseaudio-module-x11-cork-request \
+     pulseaudio-module-x11-bell \
+     consolekit', \
+    '', d)}"
+
+PULSEAUDIO_INSTALL = "${@base_contains('DISTRO_FEATURES', 'pulseaudio',  \
+    'pulseaudio-server \
+     pulseaudio-module-cli \
+     pulseaudio-misc \
+     pulseaudio-module-device-manager \
+     ${PULSEAUDIO_X11_INSTALL}', \
+    '', d)}"
+
+ALSA_INSTALL = "${@base_contains('DISTRO_FEATURES', 'alsa',  \
+    'alsa-utils \
+     alsa-tools', \
+    '', d)}"
+
+RDEPENDS_${PN} = " \
+    ${ALSA_INSTALL} \
+    ${PULSEAUDIO_INSTALL} \
+"
\ No newline at end of file
-- 
1.9.1