[meta-freescale] [meta-fsl-arm][PATCH v3 2/6] u-boot-ls1: Add recipe for Layerscape1 support

[Zhenhua Luo]

* u-boot-ls1-tools-native: provides the tcl script for endian swap
* u-boot-ls1: the u-boot recipes for ls1021aqds and ls1021atwr support

Signed-off-by: Zhenhua Luo <zhenhua.luo at freescale.com>
---
 .../u-boot/u-boot-ls1-tools-native_2013.10.bb      | 12 +++++++++++
 recipes-bsp/u-boot/u-boot-ls1.inc                  | 14 +++++++++++++
 recipes-bsp/u-boot/u-boot-ls1_2013.10.bb           | 24 ++++++++++++++++++++++
 3 files changed, 50 insertions(+)
 create mode 100644 recipes-bsp/u-boot/u-boot-ls1-tools-native_2013.10.bb
 create mode 100644 recipes-bsp/u-boot/u-boot-ls1.inc
 create mode 100644 recipes-bsp/u-boot/u-boot-ls1_2013.10.bb

diff --git a/recipes-bsp/u-boot/u-boot-ls1-tools-native_2013.10.bb b/recipes-bsp/u-boot/u-boot-ls1-tools-native_2013.10.bb
new file mode 100644
index 0000000..2a4994a
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-ls1-tools-native_2013.10.bb
@@ -0,0 +1,12 @@
+require u-boot-ls1.inc
+
+inherit native
+
+do_compile () {
+}
+
+do_install () {
+    install -d ${D}/${bindir}
+    install -m 755 ${S}/byte_swap.tcl ${D}/${bindir}
+}
+
diff --git a/recipes-bsp/u-boot/u-boot-ls1.inc b/recipes-bsp/u-boot/u-boot-ls1.inc
new file mode 100644
index 0000000..ca84047
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-ls1.inc
@@ -0,0 +1,14 @@
+LICENSE = "GPLv2 & BSD-3-Clause & BSD-2-Clause & LGPL-2.0 & LGPL-2.1"
+LIC_FILES_CHKSUM = " \
+    file://Licenses/gpl-2.0.txt;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+    file://Licenses/bsd-2-clause.txt;md5=6a31f076f5773aabd8ff86191ad6fdd5 \
+    file://Licenses/bsd-3-clause.txt;md5=4a1190eac56a9db675d58ebe86eaf50c \
+    file://Licenses/lgpl-2.0.txt;md5=5f30f0716dfdd0d91eb439ebec522ec2 \
+    file://Licenses/lgpl-2.1.txt;md5=4fbd65380cdd255951079008b364516c \
+"
+
+SRCBRANCH = "LS1-dev"
+SRC_URI = "git://git.freescale.com/layerscape/ls1021a/u-boot.git;branch=${SRCBRANCH}"
+SRCREV = "48bfc6985a0524bc5c388bb9a9a6a6bc4a121ec5"
+
+S = "${WORKDIR}/git"
diff --git a/recipes-bsp/u-boot/u-boot-ls1_2013.10.bb b/recipes-bsp/u-boot/u-boot-ls1_2013.10.bb
new file mode 100644
index 0000000..f50c144
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-ls1_2013.10.bb
@@ -0,0 +1,24 @@
+require recipes-bsp/u-boot/u-boot.inc
+require u-boot-ls1.inc
+inherit fsl-u-boot-localversion
+
+LOCALVERSION ?= "+ls1"
+
+DEPENDS += "u-boot-ls1-tools-native"
+PROVIDES += "u-boot"
+
+do_compile_append () {
+    case "${UBOOT_MACHINE}" in
+        *spi*) tclsh byte_swap.tcl ${S}/u-boot.bin ${S}/u-boot.swap.bin 8 
+        mv ${S}/u-boot.swap.bin ${S}/u-boot.bin;;
+    esac
+}
+
+PACKAGES += "${PN}-images"
+FILES_${PN}-images += "/boot"
+
+ALLOW_EMPTY_${PN} = "1"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE = "(ls102xa)"
+
-- 
1.9.3