[meta-freescale] [meta-fsl-demos][PATCH 1/7] fsl-gpu-sdk: create version 1.1 recipe

[Rogerio Nunes]

Hi Daiane,

On Wed, Feb 26, 2014 at 10:54 AM, Daiane Angolini <daiane.list at gmail.com> wrote:
> On Wed, Feb 26, 2014 at 2:03 AM,  <ronunes at gmail.com> wrote:
>> From: Evan Kotara <evan.kotara at freescale.com>
>>
>> If both X11 and Wayland are in DISTRO_FEATURES, prefer X11
>
> Sorry, Rogerio, but I think a more elaborated commit log is missing here.
>
> From your cover letter, it looks like this recipe replaces another
> one. But from this patch it only includes a new one.
>

Yes, this first patch is a squash of two other patches from FSL
release layer that only include the new recipe for the gpu sdk. I
tried to preserve as much as possible from the original commits, and I
should probably add this info to the commit log too. I'll do that.

And I remove the old recipe in another patch. I'd rather keep it this
way, but I can add a comment.

> Daiane
>>
>> Signed-off-by: Evan Kotara <evan.kotara at freescale.com>
>> Signed-off-by: Rogerio Nunes <rogerio.nunes at freescale.com>
>> ---
>>  recipes-graphics/fsl-gpu-sdk/fsl-gpu-sdk_1.1.bb | 40 +++++++++++++++++++++++++
>>  1 file changed, 40 insertions(+)
>>  create mode 100644 recipes-graphics/fsl-gpu-sdk/fsl-gpu-sdk_1.1.bb
>>
>> diff --git a/recipes-graphics/fsl-gpu-sdk/fsl-gpu-sdk_1.1.bb b/recipes-graphics/fsl-gpu-sdk/fsl-gpu-sdk_1.1.bb
>> new file mode 100644
>> index 0000000..812e23d
>> --- /dev/null
>> +++ b/recipes-graphics/fsl-gpu-sdk/fsl-gpu-sdk_1.1.bb
>> @@ -0,0 +1,40 @@
>> +SUMMARY = "Freescale GPU SDK Samples"
>> +DESCRIPTION = "Set of sample applications for Freescale GPU"
>> +LICENSE = "Proprietary"
>> +LIC_FILES_CHKSUM = "file://COPYING;md5=44e96dac83a60d6c21a6055f7b31cf0c"
>> +DEPENDS = "virtual/libgles1 virtual/libgles2 ${WL_DEPENDS}"
>> +WL_DEPENDS = "${@base_contains('DISTRO_FEATURES', 'wayland', 'wayland', '', d)}"
>> +
>> +inherit fsl-eula-unpack
>> +
>> +SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.bin;fsl-eula=true"
>> +SRC_URI[md5sum] = "7cf0e66cfc6202a51bdd42573e601e6a"
>> +SRC_URI[sha256sum] = "89e3753b343b67e3a0d82fe3e96f0b388e73a650c2a00c767cf67efce7d0c217"
>> +
>> +S = "${WORKDIR}/${PN}-${PV}"
>> +
>> +SUPPORTED_APIS = "GLES1.1 GLES2.0 ${@base_contains('DISTRO_FEATURES', 'x11', '', 'OpenVG', d)}"
>> +MAKEFILE_NO_X11 = "${@base_contains('DISTRO_FEATURES', 'wayland', 'Makefile.wl', 'Makefile.fbdev', d)}"
>> +MAKEFILE = "${@base_contains('DISTRO_FEATURES', 'x11', 'Makefile.x11', '${MAKEFILE_NO_X11}', d)}"
>> +
>> +EXTRA_OEMAKE += "YOCTO_BUILD=1"
>> +
>> +do_compile () {
>> +    export ROOTFS=${STAGING_DIR_HOST}
>> +    for API in ${SUPPORTED_APIS}; do
>> +        cd "${S}/Samples/${API}"
>> +        oe_runmake -f "${MAKEFILE}"
>> +    done
>> +}
>> +
>> +do_install () {
>> +    install -d "${D}/opt/${PN}"
>> +    for API in ${SUPPORTED_APIS}; do
>> +        cd "${S}/Samples/${API}"
>> +        oe_runmake -f "${MAKEFILE}" install
>> +        cp -r bin/* "${D}/opt/${PN}"
>> +    done
>> +}
>> +
>> +FILES_${PN} += "/opt/${PN}"
>> +FILES_${PN}-dbg += "/opt/${PN}/*/.debug"
>> --
>> 1.8.3.2
>>
>> _______________________________________________
>> meta-freescale mailing list
>> meta-freescale at yoctoproject.org
>> https://lists.yoctoproject.org/listinfo/meta-freescale