[meta-freescale] [meta-fsl-arm-extra][PATCH v3 2/4] cgtqmx6: Update Congatec-QMX6 bootloader support

[Otavio Salvador]

On Thu, Aug 21, 2014 at 11:12 AM, Alex de Cabo
<alejandro.de-cabo-garcia at congatec.com> wrote:
> Provides the recipe to use 2013.04 U-boot version
>
> Signed-off-by: Alex de Cabo <alejandro.de-cabo-garcia at congatec.com>
> ---
>  recipes-bsp/u-boot/u-boot-qmx6_2013.04.bb | 41 +++++++++++++++++++++++++++++++
>  1 file changed, 41 insertions(+)
>  create mode 100644 recipes-bsp/u-boot/u-boot-qmx6_2013.04.bb
>
> diff --git a/recipes-bsp/u-boot/u-boot-qmx6_2013.04.bb b/recipes-bsp/u-boot/u-boot-qmx6_2013.04.bb
> new file mode 100644
> index 0000000..08d8a27
> --- /dev/null
> +++ b/recipes-bsp/u-boot/u-boot-qmx6_2013.04.bb
> @@ -0,0 +1,41 @@
> +# Congatec QMX6 u-boot
> +
> +require recipes-bsp/u-boot/u-boot.inc
> +
> +LICENSE = "GPLv2+"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=1707d6db1d42237583f50183a5651ecb"
> +
> +
> +PROVIDES += "u-boot"
> +
> +PV = "2013.04"
> +
> +SRCREV = "6388c474189b42c07bb865dd604c74483da099f3"
> +SRCBRANCH = "cgt_imx_v2013.04_3.10.17_1.0.0"
> +
> +SRC_URI = "git://git.congatec.com/arm/qmx6_uboot.git;protocol=http;branch=${SRCBRANCH} \
> +"

S should be defined here.

> +do_install() {
> +       install -d ${D}/boot
> +       install -m 0644 ${S}/u-boot.${UBOOT_CONFIG}.imx ${D}/boot
> +}
> +
> +do_deploy() {
> +       install ${S}/u-boot.${UBOOT_CONFIG}.imx \
> +            ${DEPLOYDIR}/
> +
> +       install ${S}/u-boot.${UBOOT_CONFIG}.imx \
> +           ${DEPLOYDIR}/u-boot-cgtqmx6.imx
> +}

This is not needed. You should use:

UBOOT_MAKE_TARGET and UBOOT_BINARY in machine conf. So you can drop this code.


> +S = "${WORKDIR}/git"

Move to above.

> +EXTRA_OEMAKE += 'HOSTSTRIP=true'

Not needed.

> +FILES_${PN} = "\
> +               /boot/u-boot.${UBOOT_CONFIG}.imx \
> +"

Not needed.

> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +COMPATIBLE_MACHINE = "(cgtqmx6)"

Ok.

-- 
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854            Mobile: +1 (347) 903-9750