[meta-freescale] [meta-fsl-ppc 25/42] fmc_git: add recipe

[McClintock Matthew-B29882]

Applied to master.

-M

On Wed, Jan 30, 2013 at 2:51 AM, Zhenhua Luo <zhenhua.luo at freescale.com> wrote:
> From: Ting Liu <b28495 at freescale.com>
>
> Signed-off-by: Ting Liu <b28495 at freescale.com>
> ---
>  recipes-ucode/fmc/fmc_git.bb |   45 ++++++++++++++++++++++++++++++++++++++++++
>  1 file changed, 45 insertions(+)
>  create mode 100644 recipes-ucode/fmc/fmc_git.bb
>
> diff --git a/recipes-ucode/fmc/fmc_git.bb b/recipes-ucode/fmc/fmc_git.bb
> new file mode 100644
> index 0000000..c5a3bc1
> --- /dev/null
> +++ b/recipes-ucode/fmc/fmc_git.bb
> @@ -0,0 +1,45 @@
> +DESCRIPTION = "Frame Manager Configuration tool"
> +SECTION = "fmc"
> +LICENSE = "MIT"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=a504ab5a8ff235e67c7301214749346c"
> +
> +SRC_URI = "git://git.freescale.com/ppc/sdk/fmc.git"
> +SRCREV = "274ff60dd9d7dd9f881deeb86c2c4b8a342e55d1"
> +
> +DEPENDS = "libxml2 fmlib tclap"
> +
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +
> +S = "${WORKDIR}/git"
> +
> +EXTRA_OEMAKE = 'FMD_USPACE_HEADER_PATH="${STAGING_INCDIR}/fmd" \
> +    FMD_USPACE_LIB_PATH="${STAGING_LIBDIR}" LIBXML2_HEADER_PATH="${STAGING_INCDIR}/libxml2" \
> +    TCLAP_HEADER_PATH="${STAGING_INCDIR}" '
> +EXTRA_OEMAKE_virtclass-native = 'FMCHOSTMODE=1 FMD_USPACE_HEADER_PATH="${STAGING_INCDIR}/fmd" \
> +    FMD_USPACE_LIB_PATH="${STAGING_LIBDIR}" LIBXML2_HEADER_PATH="${STAGING_INCDIR}/libxml2" \
> +    TCLAP_HEADER_PATH="${STAGING_INCDIR}" '
> +
> +do_compile () {
> +    if [ "b4860qds" = "${MACHINE}" ] || [ "b4420qds" = "${MACHINE}" ];then
> +        EXTRA_OEMAKE_PLATFORM="b4860qds"
> +    elif [ "t4240qds" = "${MACHINE}" ] || [ "t4160qds" = "${MACHINE}" ];then
> +        EXTRA_OEMAKE_PLATFORM="t4240qds"
> +    elif [ "p1023rds" = "${MACHINE}" ];then
> +        EXTRA_OEMAKE_PLATFORM="p1023rds"
> +    else
> +        EXTRA_OEMAKE_PLATFORM=""
> +    fi
> +    oe_runmake MACHINE=${EXTRA_OEMAKE_PLATFORM} -C source
> +}
> +
> +do_install () {
> +    install -d ${D}/${bindir}
> +    install -m 755 ${S}/source/fmc ${D}/${bindir}/fmc
> +
> +    install -d ${D}/etc/fmc/config
> +    install -m 644 ${S}/etc/fmc/config/hxs_pdl_v3.xml ${D}/etc/fmc/config
> +}
> +
> +PARALLEL_MAKE = ""
> +
> +BBCLASSEXTEND = "native"
> --
> 1.7.9.5
>
>
> _______________________________________________
> meta-freescale mailing list
> meta-freescale at yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-freescale