[meta-freescale] [meta-fsl-arm-extra][PATCH v3 3/3] nitrogen6x: Add machine definition

[Otavio Salvador]

This adds the machine definition to Nitrogen6x from Boundary Devices.
More information at:

http://boundarydevices.com/products/nitrogen6x-board-imx6-arm-cortex-a9-sbc/

In order to take advance of same code used for imx6qsabrelite (on
linux-imx, u-boot, imx-firmaware), we use a MACHINEOVERRIDES trick, so
imx6qsabrelite is taken as a fallback for nitrogen6x machine.

To ensure the boot scripts are available at rootfs time, the do_deploy
task of u-boot-script-boundary is added as a dependency of do_rootfs.

Change-Id: I8bd0b80d2ad8e8741391ec178c10abd75218542e
Signed-off-by: Otavio Salvador <otavio at ossystems.com.br>
---
 conf/machine/nitrogen6x.conf |   30 ++++++++++++++++++++++++++++++
 1 file changed, 30 insertions(+)
 create mode 100644 conf/machine/nitrogen6x.conf

diff --git a/conf/machine/nitrogen6x.conf b/conf/machine/nitrogen6x.conf
new file mode 100644
index 0000000..d668eb2
--- /dev/null
+++ b/conf/machine/nitrogen6x.conf
@@ -0,0 +1,30 @@
+#@TYPE: Machine
+#@NAME: Nitrogen6X
+#@DESCRIPTION: Machine configuration for Boundary Devices Nitrogen6X
+
+# We need to override the default before everything
+MACHINEOVERRIDES = "${MACHINE}:imx6qsabrelite"
+
+include conf/machine/include/imx-base.inc
+include conf/machine/include/tune-cortexa9.inc
+
+SOC_FAMILY = "mx6q:mx6"
+
+PREFERRED_PROVIDER_u-boot = "u-boot-boundary"
+
+# Use SPI NOR U-Boot by default
+IMAGE_BOOTLOADER ?= ""
+
+# Ensure boot scripts will be available at rootfs time
+do_rootfs[depends] += "u-boot-script-boundary:do_deploy"
+
+# Boot scripts to install
+BOOT_SCRIPTS = "6x_bootscript-${MACHINE}:6x_bootscript"
+
+UBOOT_MACHINE = "nitrogen6X_config"
+
+SERIAL_CONSOLE = "115200 ttymxc1"
+
+MACHINE_EXTRA_RRECOMMENDS += "linux-firmware-wl12xx"
+
+MACHINE_FEATURES += " pci wifi bluetooth"
-- 
1.7.10.4