[meta-freescale] [meta-fsl-arm-extra][PATCH v2 2/3] u-boot-script-boundary: Add recipe to deploy the boot scripts

[Otavio Salvador]

The recipe deploys the scripts used by Boundary Devices to detect and
choose video output, load kernel and etc...

Change-Id: Ic4685c60ba1470a1548629e294ea8aa48473cd0e
Signed-off-by: Otavio Salvador <otavio at ossystems.com.br>
---
 recipes-bsp/u-boot/u-boot-script-boundary_git.bb |   46 ++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 recipes-bsp/u-boot/u-boot-script-boundary_git.bb

diff --git a/recipes-bsp/u-boot/u-boot-script-boundary_git.bb b/recipes-bsp/u-boot/u-boot-script-boundary_git.bb
new file mode 100644
index 0000000..f1f1ac3
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-script-boundary_git.bb
@@ -0,0 +1,46 @@
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=1707d6db1d42237583f50183a5651ecb"
+COMPATIBLE_MACHINE = "(imx6qsabrelite|nitrogen6x)"
+DEPENDS = "u-boot-mkimage-native"
+
+PV = "v2013.01+git${SRCPV}"
+
+SRCREV = "d6b05d35b8b29392e71fdd8fa43d5cb8bd4fe276"
+SRC_URI = "git://github.com/boundarydevices/u-boot-imx6.git"
+
+S = "${WORKDIR}/git"
+
+inherit deploy
+
+do_mkimage () {
+    uboot-mkimage  -A arm -O linux -T script -C none -a 0 -e 0 \
+                   -n "boot script" -d board/boundary/${MACHINE}/6x_bootscript.txt \
+                   board/boundary/${MACHINE}/6x_bootscript
+
+    uboot-mkimage  -A arm -O linux -T script -C none -a 0 -e 0 \
+                   -n "upgrade script" -d board/boundary/${MACHINE}/6x_upgrade.txt \
+                   board/boundary/${MACHINE}/6x_upgrade
+}
+
+addtask mkimage after do_compile before do_install
+
+do_deploy () {
+    install -d ${DEPLOYDIR}
+    install ${S}/board/boundary/${MACHINE}/6x_bootscript \
+            ${DEPLOYDIR}/6x_bootscript-${MACHINE}-${PV}-${PR}
+    install ${S}/board/boundary/${MACHINE}/6x_upgrade \
+            ${DEPLOYDIR}/6x_upgrade-${MACHINE}-${PV}-${PR}
+
+    cd ${DEPLOYDIR}
+    rm -f 6x_bootscript-${MACHINE} 6x_upgrade-${MACHINE}
+    ln -sf 6x_bootscript-${MACHINE}-${PV}-${PR} 6x_bootscript-${MACHINE}
+    ln -sf 6x_upgrade-${MACHINE}-${PV}-${PR} 6x_upgrade-${MACHINE}
+}
+
+addtask deploy before do_build after do_compile
+
+do_compile[noexec] = "1"
+do_install[noexec] = "1"
+do_populate_sysroot[noexec] = "1"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
-- 
1.7.10.4